Pwhite

Another popular member of the Pattern family is Pwhite. It is an equal distribution random number generator (the name comes from “white noise”). For example, Pwhite(100, 500) will get you random numbers between 100 and 500.

(
Pbind(
    \freq, Pwhite(100, 500),
    \dur, Prand([0.15, 0.25, 0.3], inf),
    \amp, 0.2,
    \legato, 0.3
).trace.play;
)

The example above also shows another helpful trick: the message trace just before play. It prints out in the Post window the values chosen for every event. Very useful for debugging or simply to understand what is going on!

Pay attention to the differences between Pwhite and Prand: they take in different arguments, and they do different things. Inside Pwhite’s parentheses you only need to provide a low and a high boundary: Pwhite(low, high). Random numbers will be chosen from within that range. Prand, on the other hand, takes in a list of items (necessarily between square brackets), and a number of repeats: Prand([list, of, items], repeats). Random items will be chosen from the list.

Play around with both and make sure you fully understand the difference.

TIP: A Pwhite with two integer numbers will generate only integers. For example, Pwhite(100, 500) will output numbers like 145, 568, 700, but not 145.6, 450.32, etc. If you want floating point numbers in your output, write Pwhite(100, 500.0). This is very useful for, say, amplitudes: if you write Pwhite(0, 1) you are only getting 0 or 1, but write Pwhite(0, 1.0) and you will get everything in between.

Try the following questions to test your new knowledge:

1. What is the difference in output between Pwhite(0, 10) and Prand([0, 4, 1, 5, 9, 10, 2, 3], inf)?

2. If you need a stream of integer numbers chosen randomly between 0 and 100, could you use a Prand?

3. What is the difference in output between Pwhite(0, 3) and Prand([0, 1, 2, 3], inf)? What if you write Pwhite(0, 3.0)?

4. Run the examples below. We use \note instead of \degree in order to play a C minor scale (which includes black keys). The list [0, 2, 3, 5, 7, 8, 11, 12] has eight numbers in it, corresponding to pitches C, D, E\(\flat\), F, G, A\(\flat\), B, C, but how many events does each example actually play? Why?

   // Pseq
   (
   Pbind(
       \note, Pseq([0, 2, 3, 5, 7, 8, 11, 12], 4),
       \dur, 0.15;
   ).play;
   )
   
   // Pseq
   (
   Pbind(
       \note, Prand([0, 2, 3, 5, 7, 8, 11, 12], 4),
       \dur, 0.15;
   ).play;
   )
   
   // Pwhite
   (
   Pbind(
       \note, Pseq([0, 2, 3, 5, 7, 8, 11, 12], 4),
       \dur, Pwhite(0.15, 0.5);
   ).play;
   )

Answers below.¹